{-

abacus
Copyright (C) Jonathan Lamothe <jonathan@jlamothe.net>

This program is free software: you can redistribute it and/or modify
it under the terms of the GNU Affero General Public License as
published by the Free Software Foundation, either version 3 of the
License, or (at your option) any later version.

This program is distributed in the hope that it will be useful, but
WITHOUT ANY WARRANTY; without even the implied warranty of
MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU
Affero General Public License for more details.

You should have received a copy of the GNU Affero General Public
License along with this program.  If not, see
<https://www.gnu.org/licenses/>.

-}

module AbacusSpec (spec) where

import Data.Maybe (fromJust)
import Lens.Micro.Platform ((^.), (&), (.~), (%~))
import Test.Hspec
  ( Spec
  , context
  , describe
  , it
  , shouldBe
  )

import Abacus
import Abacus.Internal

import qualified Abacus.AppSpec as App

spec :: Spec
spec = describe "Abacus" $ do
  newAbacusSpec
  getNumBeadsSpec
  getNumRungsSpec
  getRungSpec
  setRungSpec
  rungLSpec
  resetAbacusSpec
  rungListSpec
  App.spec

newAbacusSpec :: Spec
newAbacusSpec = describe "newAbacusSpec" $ mapM_
  ( \(desc, beads, rungs, expected) -> context desc $ let
    actual = newAbacus beads rungs
    in it ("should be " ++ show expected) $
      actual `shouldBe` expected
  )
  [ ( "valid",    10, 3, Just $ Abacus 10 [0, 0, 0] )
  , ( "no beads", 0,  3, Nothing                    )
  , ( "no rungs", 10, 0, Nothing                    )
  ]

getNumBeadsSpec :: Spec
getNumBeadsSpec = describe "getNumBeads" $ mapM_
  ( \(desc, input, expected) -> context desc $ let
    actual = getNumBeads input
    in it ("should be " ++ show expected) $
      actual `shouldBe` expected
  )
  [ ( "one bead",  oneBead,  1  )
  , ( "ten beads", tenBeads, 10 )
  ] where
    oneBead = build 1
    tenBeads = build 10
    build n = fromJust $ newAbacus n 10

getNumRungsSpec :: Spec
getNumRungsSpec = describe "getNumRungs" $ mapM_
  ( \(desc, input, expected) -> context desc $ let
    actual = getNumRungs input
    in it ("should be " ++ show expected) $
      actual `shouldBe` expected
  )
  [ ( "one rung",  oneRung,  1  )
  , ( "ten rungs", tenRungs, 10 )
  ] where
    oneRung = build 1
    tenRungs = build 10
    build n = fromJust $ newAbacus 10 n

getRungSpec :: Spec
getRungSpec = describe "getRung" $ mapM_
  ( \(desc, rung, expected) -> context desc $ let
    actual = getRung rung abacus
    in it ("should be " ++ show expected) $
      actual `shouldBe` expected
  )
  [ ( "first rung",     0, Just 2  )
  , ( "last rung",      2, Just 5  )
  , ( "negative rung", -1, Nothing )
  , ( "too large",      3, Nothing )
  ] where
    abacus = Abacus 10 [2, 3, 5]

setRungSpec :: Spec
setRungSpec = describe "setRung" $ mapM_
  ( \(desc, rung, val, expected) -> context desc $ let
    actual = setRung rung val $ mkA [2, 3, 5]
    in it ("should be " ++ show expected) $
      actual `shouldBe` expected
  )
  [ ( "first rung",     0, 10, mkA [10,  3,  5] )
  , ( "last rung",      2, 10, mkA [ 2,  3, 10] )
  , ( "negative rung", -1, 10, mkA [ 2,  3,  5] )
  , ( "large rung",     3, 10, mkA [ 2,  3,  5] )
  , ( "negative value", 1, -1, mkA [ 2,  0,  5] )
  , ( "large value",    1, 11, mkA [ 2, 10,  5] )
  ] where
    mkA = Abacus 10

rungLSpec :: Spec
rungLSpec = describe "rungL" $ do
  let
    mkA = Abacus 10
    abacus = mkA [2, 3, 5]
  context "getter" $
    context "rung 1" $
      it "should be 3" $
        abacus^.rungL 1 `shouldBe` 3
  context "setter" $ mapM_
    ( \(desc, rung, val, expected) -> context desc $ let
      actual = abacus & rungL rung .~ val
      in it ("should be " ++ show expected) $
        actual `shouldBe` expected
    )
    [ ( "valid rung and value", 1,  7, mkA [2, 7, 5] )
    , ( "bad rung",            -1,  7, abacus        )
    , ( "bad value",            1, -1, mkA [2, 0, 5] )
    ]
  context "modifier" $ mapM_
    ( \(desc, rung, expected) -> context desc $ let
      actual = abacus & rungL rung %~ succ
      in it ("should be " ++ show expected) $
        actual `shouldBe` expected
    )
    [ ( "valid rung",    1, mkA [2, 4, 5] )
    , ( "invalid rung", -1, mkA [2, 3, 5] )
    ]

resetAbacusSpec :: Spec
resetAbacusSpec = describe "resetAbacus" $ let
  expected = Abacus 10 [0, 0, 0]
  in it ("should be " ++ show expected) $ let
    actual = resetAbacus $ Abacus 10 [2, 3, 5]
    in expected `shouldBe` actual

rungListSpec :: Spec
rungListSpec = describe "rungList" $ let
  expected = [2, 3, 5]
  in it ("should be " ++ show expected) $ let
    actual = rungList $ Abacus 10 [2, 3, 5]
    in expected `shouldBe` actual

--jl